collision.odin

package main

CollisionSystem :: struct{
	colliders:[dynamic]Collider,
}
collision_system:^CollisionSystem

Collider :: struct{
	using rect:Rect,
	ref:EntityRef,
}

_collision_system_init :: proc(){
	collision_system = new(CollisionSystem)
	collision_system.colliders = make([dynamic]Collider)
}

_collision_system_update :: proc(){
	
}

collision :: proc(rect:Rect, $T:typeid, ignoreInd:=-1) -> ^T{
	for collider,i in collision_system.colliders{
		if i == ignoreInd do continue

		if rects_overlap(rect, collider) && typeid_of(T) == collider.ref.entityType{
			return entity_get(collider.ref, T)
		}
	}

	return nil
}

collider_make :: proc(rect:Rect, ref:EntityRef) -> int{
	append(&collision_system.colliders, Collider{
		rect,
		ref
	})

	return len(collision_system.colliders) - 1
}

collider_get :: proc(ind:int) -> ^Rect{
	return &collision_system.colliders[ind].rect
}

move_and_collide :: proc(speed:Vec2, rect:^Rect){
	newRect := rect^
	signSpeed := sign(speed)
	absSpeed := abs(speed)

	//vertical movement
	for i in 0..<absSpeed.y{
		newRect.y += signSpeed.y
		if collision(newRect, Block) != nil{
			newRect.y -= signSpeed.y
			break
		}
	}

	//horizontal movement
	for i in 0..<absSpeed.x{
		newRect.x += signSpeed.x
		if collision(newRect, Block) != nil{
			newRect.x -= signSpeed.x
			break
		}
	}

	rect.pos = newRect.pos
}